Starting day 19, blending.

19-blending/shaders/12-frag.glsl

@@ -0,0 +1,67 @@
+#version 330 core
+struct Material {
+  sampler2D diffuse;
+  sampler2D specular;
+  float shininess;
+};
+
+struct Light {
+  vec3 direction;
+  vec3 position;
+  vec3 diffuse;
+  vec3 specular;
+  vec3 ambient;
+
+  float constant;
+  float linear;
+  float quadratic;
+  float cutOff;
+  float outerCutOff;
+};
+
+out vec4 FragColor;
+in vec3 FragPos;
+in vec3 Normal;
+in vec2 TexCoords;
+
+uniform vec3 viewPos;
+uniform Light light;
+uniform Material material;
+
+void main()
+{
+  vec3 lightDir = normalize(light.position - FragPos);
+
+  vec3 mat_tex = vec3(texture(material.diffuse, TexCoords));
+  vec3 spec_tex = vec3(texture(material.specular, TexCoords));
+  vec3 ambient = light.ambient * mat_tex;
+
+  vec3 norm = normalize(Normal);
+  float diff = max(dot(norm, lightDir), 0.0);
+  vec3 diffuse = light.diffuse * diff * mat_tex;
+
+  vec3 viewDir = normalize(viewPos - FragPos);
+  vec3 reflectDir = reflect(-lightDir, norm);
+
+  float spec = pow(max(dot(viewDir, reflectDir), 0.0), material.shininess);
+
+  vec3 specular = light.specular * spec * spec_tex;
+
+  // splotlight
+  float theta = dot(lightDir, normalize(-light.direction));
+  float epsilon = light.cutOff - light.outerCutOff;
+  float intensity = clamp((theta - light.outerCutOff) / epsilon, 0.0, 1.0);
+  diffuse *= intensity;
+  specular *= intensity;
+
+  // determine attenuation based on light distance
+  float distance = length(light.position - FragPos);
+  float attenuation = 1.0 / (light.constant + light.linear * distance + light.quadratic * (distance * distance));
+
+  ambient *= attenuation;
+  diffuse *= attenuation;
+  specular *= attenuation;
+
+  vec3 result = ambient + diffuse + specular;
+  FragColor = vec4(result, 1.0);
+}